Amiga Format CD 44/Amiga Format CD44 (1999-08-26)(Future Publishing)(GB)(Track 1 of 3)[!][issue 1999-10].iso/-in_the_mag-/basics/amos/multiwindows.lha/MultiWindows/Multiwin.amos/Multiwin.amosSourceCode

AMOS Source Code | 1999-01-04 | 64KB | 2,278 lines

Set Buffer 30
'
' ** Welcome to MultiWindows, an experiment by Martin Cameron.
'
'    This is based on some interface code from Turbo Plus.
'
'    Ever wanted to make a cool interface for an AMOS program?
'    These procs give you everything you need - windows, buttons,
'    sliders, checkboxes, file selectors etc. All you have to worry
'    about are a few screen coordinates.
'
'    That was the idea, anyway. What I've ended up with is a 100k
'     monster that causes grief to any minor programming exercise.
'     It's still a bit cool, having custom windows, though.
'
'
'
'    Some essential info follows....
'
'
'    Always bring a window to the front before changing it's contents!
'     This is BLOODY IMPORTANT, or you'll get pissed off..
'
'
'    Do NOT create window 0! The Array space is used to store some
'     global things, and the interface may not work!
'
'    The screen after WINSCREEN is used as a double buffer, and should
'     be opened before it so it is out of sight. It must have the same
'     dimensions/ no. colours as winscreen.
'
'    Windows can be slow on anything above a 4 colour screen. When
'     using 4 colours, set VDGREY to the same colour as VGREY.
'
'     When creating buttons or setting zones, don't use gadnum 1 to 4,
'      because these are the dragbar/closegadget etc :
'
'         Winzone 1 : Reserved for close gadget (raises WINCLOSED)
'         Winzone 2 : Reserved for Depth gadget (sends window to back)
'         Winzone 3 : reserved for size (raises WINSIZED)
'         Winzone 4 : Reserved for drag bar
'
'    Winzone 5 and above : Free for your buttons.
'
'    Using sizegadgets are a pain... Once sized, you MUST :
'      1) Redraw the window's framework.
'      2) Call the create procedures for all the gadgets on that window
'              This means storing temporary values for the old gadgets
'              and writing them back once the new gadget is drawn.
'              See the doc for the info you will need!
'         ** Not any more! Use gad_move to redraw and reposition
'            gadgets after a resize! - Mart June 98
'
'
'
'   Final note .. This is FREE!   Do what the hell you like with it!
'    This means, of course - Debug it, It's bloody well full of 'em.
'
'
'  Send warez/bugs to :          Mart,
'                                46 Ribby Road,
'                                Kirkham, Lancs, PR4 2BA, UK.
'
'
'
'
'
'
'  Wincount - Number of windows to reserve buffer space for.
'             The last window is always used by the file selector and
'             requestor, so don't use it - it will be overwritten!
'
'  When using the file selector, set gadcount to at least 15, or you
'   will get an error! If using the requestor, gadcount at least 6.
'
' In any case, it should never be below 4.
'
WINCOUNT=10 : GADCOUNT=20 : Set Dir 60
'
'
'
' For more complex programs, such as a file selector, you will need to
'  know what these arrays are for. See the doc file.
'
'
Dim WININFO(WINCOUNT,8),WINORDER(WINCOUNT),WINZONE(WINCOUNT,GADCOUNT,4)
Global WININFO(),WINORDER(),WINZONE(),WINCOUNT,GADCOUNT
Global WINSIZED,WINSELECTED,WINCLOSED
Global VBLACK,VWHITE,VGREY,VBLUE,VDGREY
'
Dim GADTEXT$(WINCOUNT,GADCOUNT),GADSTUFF(WINCOUNT,GADCOUNT,6)
Dim FILELIST$(300),GADRADIO(WINCOUNT,GADCOUNT)
Global GADTEXT$(),GADSTUFF(),FILELIST$(),FILEDIR$,GADRADIO()
'
'
'
'
'
Screen Open 2,640,256,8,Hires : Curs Off : Flash Off : Cls 0
Screen Open 1,640,256,8,Hires : Curs Off : Flash Off : Cls 0
Palette $0,$FFF,$AAA,$68B,$777 : Proc WIN_SETCOLOURS[0,1,2,3,4]
'
'
'
'
'
'
'
'
'
'  ***  test program. Remove this code below when writing your stuff.
'
'
'
' Set windows system up using screens 1 and 2
Proc WIN_SETUP[1]
'
N=1
Proc WIN_CREATE[N,N+10,N+20,300,150,300,150,630,240]
Proc WIN_FRAMEWORK[N,3,0,7,4,"TestWin"]
'
GAD_BUTTON_CREATE[N,5,10,20,11,"Select File"]
'
GAD_CYCLE_CREATE[N,6,10,40,10,"Testcycle"]
GAD_CYCLE_ADDITEM[N,6,"Cycle2"]
GAD_CYCLE_ADDITEM[N,6,"Cycle3"]
'
GAD_TEXT_CREATE[N,7,10,55,20,"TestText",0]
GAD_DISPLAY_CREATE[N,8,10,70,20,"Display"]

GAD_CHECKBOX_CREATE[N,9,140,20]

GAD_SLIDER_CREATE[N,10,275,20,20,80,5,2]
'GAD_VSLIDEBUT_CREATE[N,11,10]

GAD_HSLIDER_CREATE[N,12,10,125,200,12,5,2]
'GAD_HSLIDEBUT_CREATE[N,13,12]
GAD_SBUT_CREATE[N,13,50,100,20,20,4]

GAD_SCROLLBUT_CREATE[N,14,250,125]

GAD_RADIOBUT_CREATE[N,15,240,20,1]
GAD_RADIOBUT_CREATE[N,16,240,30,1]
GAD_RADIOBUT_CREATE[N,17,240,40,1]
GAD_RADIOBUT_CREATE[N,18,240,60,2]
GAD_RADIOBUT_CREATE[N,19,240,70,2]

Proc WIN_SETGFX[N]

'
'
'   Main loop of test program.
'
'

Do

   Proc WINSCAN : GADGET=Param


   If GADGET=5
      WIN_FILE_SELECTOR[10,10,60,"filer"]

      ' BRING WINDOW TO FRONT BEFORE CHANGING GADGET CONTENTS!!
      WINTOFRONT[1]

      GAD_TEXT_SET[1,7,Param$,0,0]
   End If

   If GADGET=6
      'Print WINSELECTED
      GAD_CYCLE_PUSH[WINSELECTED,6]
   End If

   If GADGET=7
      GAD_TEXT_INPUT[WINSELECTED,7]
      GAD_TEXT_GET[WINSELECTED,7]
      GAD_DISPLAY_SET[WINSELECTED,8,Param$]
   End If

   If GADGET=9
      GAD_CHECKBOX_TICK[WINSELECTED,9]
   End If

   If GADGET=10
      Repeat
         GAD_SLIDER_MOUSE_UPDATE[WINSELECTED,10]
      Until Mouse Key=0
      '      GAD_SLIDEOFF[WINSELECTED,10]
   End If

   If GADGET=11
      Repeat
         '         GAD_VSLIDEBUT_UPDATE[WINSELECTED,11]
      Until Mouse Key=0
      '      GAD_SLIDEOFF[WINSELECTED,11]
   End If

   If GADGET=12
      'slider loop
      Repeat
         GAD_HSLIDER_MOUSE_UPDATE[WINSELECTED,12]
      Until Mouse Key=0
      ' turn slider off - important
      '      GAD_SLIDEOFF[WINSELECTED,12]
   End If

   If GADGET=13
      '      Repeat
      Bell
      '         GAD_HSLIDEBUT_UPDATE[WINSELECTED,13]
      '      Until Mouse Key=0
      '      GAD_SLIDEOFF[WINSELECTED,13]
   End If

   If GADGET=14
      Repeat
         GAD_SCROLLBUT_UPDATE[WINSELECTED,14]
      Until Mouse Key=0
      GAD_SCROLLOFF[WINSELECTED,14]
   End If

   If GADGET>14
      GAD_RADIOBUT_PUSH[WINSELECTED,GADGET]
   End If

   If WINSIZED
      WIN_SIZE[WINSIZED]
      If Param=1
         '
         '   Check if window changed shape...
         '
         WIN_FRAMEWORK[WINSIZED,3,0,7,4,"Sizedwin"]
         '
         '   Redraw gadgets here!
         '
         For N=5 To 19
            GAD_MOVE[WINSIZED,N,WINZONE(WINSIZED,N,1),WINZONE(WINSIZED,N,2)]
         Next N
         '
         WIN_SETGFX[WINSIZED]
      End If
   End If

   If WINCLOSED=1

      GAD_REQUEST[100,100,"Request","Really close?","You can't be serious!","","       Yep        ","   Nope  "]
      If Param=1 : WIN_CLOSE[1]
         GAD_REQUEST[100,100,"Bugger..","","Now you've buggered it","","","Quit"]
      End : End If
   End If

Loop
'
'
'
'
'
'
'
'   The important bit... The Multiwindows Procedures
'
'
'
Procedure WIN_FRAMEWORK[NUM,GSTYLE,PSTYLE,PCOL1,PCOL2,TITLE$]
   X=WININFO(NUM,1)
   Y=WININFO(NUM,2)
   W=WININFO(NUM,3)-X
   H=WININFO(NUM,4)-Y
   '
   If PSTYLE=>0
      Ink PCOL1,PCOL2
      Set Pattern PSTYLE
      Bar X,Y To W+X,H+Y
      Set Pattern 0
   End If

   If GSTYLE=1
      WIN_SET_ZONE[NUM,4,4,2,W-26,11]
      GAD_RAISEBOX_CREATE[X+4,Y+2,W-26,11,2]

      WIN_SET_ZONE[NUM,2,W-19,3,15,9]
      GAD_RAISEBOX_CREATE[X+W-19,Y+3,15,9,2]
      Ink VWHITE : Draw X+W-15,Y+6 To X+W-8,Y+6
      Ink VDGREY : Draw X+W-15,Y+8 To X+W-8,Y+8
      Ink VBLACK,VGREY : Draw X+W-15,Y+9 To X+W-8,Y+9

      TEXSPC=(W-33)/8
      If Len(TITLE$)>TEXSPC
         TITLE$=Left$(TITLE$,TEXSPC)
      End If

      Text X+10,Y+10,TITLE$

   Else If GSTYLE=2

      WIN_SET_ZONE[NUM,4,4,2,W-26,11]
      GAD_RAISEBOX_CREATE[X+4,Y+2,W-26,11,2]

      WIN_SET_ZONE[NUM,1,7,4,14,7]
      GAD_RAISEBOX_CREATE[X+7,Y+4,14,7,2]

      WIN_SET_ZONE[NUM,2,W-19,3,15,9]
      GAD_RAISEBOX_CREATE[X+W-19,Y+3,15,9,2]
      Ink VWHITE : Draw X+W-15,Y+6 To X+W-8,Y+6
      Ink VDGREY : Draw X+W-15,Y+8 To X+W-8,Y+8
      Ink VBLACK,VGREY : Draw X+W-15,Y+9 To X+W-8,Y+9

      TEXSPC=(W-48)/8
      If Len(TITLE$)>TEXSPC
         TITLE$=Left$(TITLE$,TEXSPC)
      End If

      Text X+26,Y+10,TITLE$

   Else If GSTYLE=3

      WIN_SET_ZONE[NUM,4,4,2,W-26,11]
      GAD_RAISEBOX_CREATE[X+4,Y+2,W-26,11,2]

      WIN_SET_ZONE[NUM,1,7,4,14,7]
      GAD_RAISEBOX_CREATE[X+7,Y+4,14,7,2]

      WIN_SET_ZONE[NUM,2,W-19,3,15,9]
      GAD_RAISEBOX_CREATE[X+W-19,Y+3,15,9,2]
      Ink VWHITE : Draw X+W-15,Y+6 To X+W-8,Y+6
      Ink VDGREY : Draw X+W-15,Y+8 To X+W-8,Y+8
      Ink VBLACK,VGREY : Draw X+W-15,Y+9 To X+W-8,Y+9

      TEXSPC=(W-48)/8
      If Len(TITLE$)>TEXSPC
         TITLE$=Left$(TITLE$,TEXSPC)
      End If

      Text X+26,Y+10,TITLE$

      WIN_SET_ZONE[NUM,3,W-19,H-10,14,7]
      Ink VGREY : Polygon X+W-19,H+Y-3 To X+W-5,H+Y-3 To X+W-5,H+Y-10
      Ink VBLACK : Polyline X+W-19,H+Y-3 To X+W-5,H+Y-3 To X+W-5,H+Y-10
      Ink VWHITE : Draw X+W-19,H+Y-3 To X+W-5,H+Y-10

   End If
   '
   GAD_RAISEBOX_CREATE[X,Y,W,H,3]
   '
End Proc
Procedure WIN_SETGFX[NUM]
   WINX=WININFO(NUM,1)
   WINY=WININFO(NUM,2)
   WINWIDTH=WININFO(NUM,3)-WINX
   WINHEIGHT=WININFO(NUM,4)-WINY
   '
   Get Block 9000+NUM,WINX,WINY,WINWIDTH+1,WINHEIGHT+1,1
End Proc
Procedure WIN_SET_ZONE[WINNUM,GADNUM,X,Y,WIDTH,HEIGHT]
   WINZONE(WINNUM,GADNUM,1)=X
   WINZONE(WINNUM,GADNUM,2)=Y
   WINZONE(WINNUM,GADNUM,3)=X+WIDTH
   WINZONE(WINNUM,GADNUM,4)=Y+HEIGHT
End Proc
Procedure WINSCAN

   If WINSIZED>0 : WINSIZED=0 : End If
   If WINCLOSED>0 : WINCLOSED=0 : End If

   If Mouse Key=1
      XM=X Screen(X Mouse) : YM=Y Screen(Y Mouse)
      For N=1 To WINCOUNT
         NUM=WINORDER(N)
         If WININFO(NUM,0)=1
            If XM=>WININFO(NUM,1) and YM=>WININFO(NUM,2)
               If XM<=WININFO(NUM,3) and YM<=WININFO(NUM,4)
                  If N>1
                     Proc WINTOFRONT[NUM] : Exit
                  Else
                     Exit
                  End If
               End If
            End If
         End If
      Next N
      '      XM=X Screen(X Mouse) : YM=Y Screen(Y Mouse)
      WINX=WININFO(NUM,1) : WINY=WININFO(NUM,2)
      For N=1 To GADCOUNT
         If XM=>WINZONE(NUM,N,1)+WINX and YM=>WINZONE(NUM,N,2)+WINY
            If XM<=WINZONE(NUM,N,3)+WINX and YM<=WINZONE(NUM,N,4)+WINY
               GADRETURN=N : Exit
            End If
         End If
      Next N
      '
      '
      If GADRETURN<5
         If GADRETURN=4
            Proc WINDRAG[NUM]

         Else If GADRETURN=2
            XS1=WINZONE(NUM,2,1)+WININFO(NUM,1) : YS1=WINZONE(NUM,2,2)+WININFO(NUM,2)
            XS2=WINZONE(NUM,2,3)+WININFO(NUM,1) : YS2=WINZONE(NUM,2,4)+WININFO(NUM,2)
            While Mouse Key=1
               XSM=X Screen(X Mouse) : YSM=Y Screen(Y Mouse)
               If XSM=>XS1 and XSM<=XS2 and YSM=>YS1 and YSM<=YS2
                  If SELEKT=0
                     GAD_LOWERBOX_CREATE[XS1,YS1,XS2-XS1,YS2-YS1,1]
                     SELEKT=1
                  End If
               Else
                  If SELEKT=1
                     GAD_RAISEBOX_CREATE[XS1,YS1,XS2-XS1,YS2-YS1,1]
                     SELEKT=0
                  End If
               End If
            Wend
            If SELEKT=1
               GAD_RAISEBOX_CREATE[XS1,YS1,XS2-XS1,YS2-YS1,1]
               Proc WINTOBACK[NUM]
            End If

         Else If GADRETURN=1
            XS1=WINZONE(NUM,1,1)+WININFO(NUM,1) : YS1=WINZONE(NUM,1,2)+WININFO(NUM,2)
            XS2=WINZONE(NUM,1,3)+WININFO(NUM,1) : YS2=WINZONE(NUM,1,4)+WININFO(NUM,2)
            While Mouse Key=1
               XSM=X Screen(X Mouse) : YSM=Y Screen(Y Mouse)
               If XSM=>XS1 and XSM<=XS2 and YSM=>YS1 and YSM<=YS2
                  If SELEKT=0
                     GAD_LOWERBOX_CREATE[XS1,YS1,XS2-XS1,YS2-YS1,2]
                     SELEKT=1
                  End If
               Else
                  If SELEKT=1
                     GAD_RAISEBOX_CREATE[XS1,YS1,XS2-XS1,YS2-YS1,2]
                     SELEKT=0
                  End If
               End If
            Wend
            If SELEKT=1
               GAD_RAISEBOX_CREATE[XS1,YS1,XS2-XS1,YS2-YS1,2]
               WINCLOSED=NUM
            End If

         Else If GADRETURN=3
            '            Proc WIN_SIZE[NUM]
            WINSIZED=NUM
         End If

         GADRETURN=0

      Else If WINZONE(NUM,GADRETURN,0)=1 or WINZONE(NUM,GADRETURN,0)=7 or WINZONE(NUM,GADRETURN,0)=20
         GTEM=GADRETURN
         Do
            XM=X Screen(X Mouse)-WINX : YM=Y Screen(Y Mouse)-WINY
            If XM<WINZONE(NUM,GTEM,1) or XM>WINZONE(NUM,GTEM,3) or YM<WINZONE(NUM,GTEM,2) or YM>WINZONE(NUM,GTEM,4)
               If T=1
                  If WINZONE(NUM,GTEM,0)=1 : GAD_BUTTON_OUT[NUM,GTEM] : GADRETURN=0 : End If
                  If WINZONE(NUM,GTEM,0)=7 : GAD_CYCLE_OUT[NUM,GTEM] : GADRETURN=0 : End If
                  If WINZONE(NUM,GTEM,0)=20 : GAD_SBUT_OUT[NUM,GTEM] : GADRETURN=0 : End If
               T=0 : End If
            Else
               If T=0
                  If WINZONE(NUM,GTEM,0)=1 : GAD_BUTTON_IN[NUM,GTEM] : GADRETURN=GTEM : End If
                  If WINZONE(NUM,GTEM,0)=7 : GAD_CYCLE_IN[NUM,GTEM] : GADRETURN=GTEM : End If
                  If WINZONE(NUM,GTEM,0)=20 : GAD_SBUT_IN[NUM,GTEM] : GADRETURN=GTEM : End If
               T=1 : End If
            End If
            Exit If Mouse Key=0
         Loop
         If GADRETURN>0
            If WINZONE(NUM,GADRETURN,0)=1 : GAD_BUTTON_OUT[NUM,GADRETURN] : End If
            If WINZONE(NUM,GADRETURN,0)=7 : GAD_CYCLE_OUT[NUM,GADRETURN] : End If
            If WINZONE(NUM,GADRETURN,0)=20 : GAD_SBUT_OUT[NUM,GADRETURN] : End If
         End If
      End If
      If GADRETURN=0 and WINSIZED=0 : Repeat : Until Mouse Key=0 : End If
   End If
End Proc[GADRETURN]
Procedure WIN_SETUP[WINSCREEN]

   WININFO(0,0)=WINSCREEN
   Screen To Front WINSCREEN
   Screen WINSCREEN

   S=WINCOUNT : WINSIZED=0
   For N=1 To WINCOUNT
      WINORDER(N)=S : Dec S
   Next N
End Proc
Procedure WIN_CREATE[NUM,X,Y,WIDTH,HEIGHT,XSIZEMIN,YSIZEMIN,XSIZEMAX,YSIZEMAX]

   WINTOFRONT[NUM]

   SWIDTH=Screen Width(WININFO(0,0))

   WININFO(NUM,0)=1
   WININFO(NUM,1)=X
   WININFO(NUM,2)=Y

   If WIDTH=>SWIDTH : WIDTH=SWIDTH-1 : End If
   If X+WIDTH=>SWIDTH : X=SWIDTH-WIDTH-1 : End If

   WININFO(NUM,3)=X+WIDTH
   WININFO(NUM,4)=Y+HEIGHT
   WININFO(NUM,5)=XSIZEMIN
   WININFO(NUM,6)=YSIZEMIN
   WININFO(NUM,7)=XSIZEMAX
   WININFO(NUM,8)=YSIZEMAX

   WINSELECTED=NUM

End Proc
Procedure WIN_REDRAW[NUM]
   OPEN=WININFO(NUM,0)
   If OPEN=0 : Pop Proc : End If
   X=WININFO(NUM,1)
   Y=WININFO(NUM,2)
   WIDTH=WININFO(NUM,3)-X
   HEIGHT=WININFO(NUM,4)-Y
   Ink WININFO(0,1) : Bar X,Y To X+WIDTH,Y+HEIGHT
   'Trap Put Block 9000+NUM,X,Y
   Put Block 9000+NUM,X,Y
   WINSELECTED=NUM

End Proc
Procedure WINTOFRONT[NUM]

   WINSCREEN=WININFO(0,0)

   ' below needed since content of foremost win may have changed.
If WININFO(WINORDER(1),0)=1
' check if window is open or not.
   WIN_SETGFX[WINORDER(1)]
End If

   For N=1 To WINCOUNT
      If WINORDER(N)=NUM Then TMP=N : Exit
   Next N
   '
   If TMP=1 : Pop Proc : End If
   '
   For N=TMP To 2 Step -1
      WINORDER(N)=WINORDER(N-1)
   Next N
   '
   WINORDER(1)=NUM
   '
   WIN_REDRAW[WINORDER(1)]
End Proc
Procedure WIN_SELUPDATE[FAST,X,Y,X2,Y2]
   '
   ' What does the sel mean? This could be much quicker if amos supported
   '  pasting of block sections, but it doesn't .... what an arse.
   '
   WINSCREEN=WININFO(0,0)
   Screen WINSCREEN+1 : Rem double buffer

   If FAST=0 : WIN_SELBACKDROP[X,Y,X2,Y2] : End If

   For N=WINCOUNT To 1 Step -1

      WO=WINORDER(N)
      If WININFO(WO,0)=1

         WINX=WININFO(WO,1)
         WINY=WININFO(WO,2)
         WINX2=WININFO(WO,3)
         WINY2=WININFO(WO,4)

         If WINX<=X2 and WINX2=>X
            If WINY<=Y2 and WINY2=>Y
               WIN_REDRAW[WO]
            End If
         End If
      End If
   Next N

   Screen Copy WINSCREEN+1,X,Y,X2+1,Y2+1 To WINSCREEN,X,Y
   Screen WINSCREEN

   Repeat : Until Mouse Key=0

End Proc
Procedure WINTOBACK[NUM]

   ' see wintofront...
   WIN_SETGFX[WINORDER(1)]

   For N=2 To WINCOUNT
      WINORDER(N-1)=WINORDER(N)
   Next N
   WINORDER(WINCOUNT)=NUM
   '
   X=WININFO(NUM,1)
   Y=WININFO(NUM,2)
   X2=WININFO(NUM,3)
   Y2=WININFO(NUM,4)

   Proc WIN_SELUPDATE[1,X,Y,X2,Y2]

End Proc
Procedure WIN_SETCOLOURS[VBLACK,VWHITE,VGREY,VBLUE,VDGREY]
' You ain't seen me. Right?
End Proc
Procedure WINDRAG[NUM]
   X=WININFO(NUM,1)
   Y=WININFO(NUM,2)
   X2=WININFO(NUM,3)-X
   Y2=WININFO(NUM,4)-Y
   WINSCREEN=WININFO(0,0)
   '
   DX=X Screen(X Mouse)-X
   DY=Y Screen(Y Mouse)-Y
   Gr Writing 3
   '
   Repeat
      XM=X Screen(X Mouse)-DX
      If XM<0 : XM=0 : End If
      If XM+X2>Screen Width(WINSCREEN)-1 : XM=Screen Width(WINSCREEN)-X2-1 : End If
      YM=Y Screen(Y Mouse)-DY
      If YM<0 : YM=0 : End If
      If YM+Y2>Screen Height(WINSCREEN)-1 : YM=Screen Height(WINSCREEN)-Y2-1 : End If
      If OXM<>XM or OYM<>YM
         Box XM,YM To XM+X2,YM+Y2
         Box XM,YM To XM+X2,YM+Y2
      Else
         Box XM,YM To XM+X2,YM+Y2
         Do
            XX=X Screen(X Mouse)-DX
            If XX<0 : XX=0 : End If
            If XX+X2>Screen Width(WINSCREEN)-1 : XX=Screen Width(WINSCREEN)-X2-1 : End If
            YY=Y Screen(Y Mouse)-DY
            If YY<0 : YY=0 : End If
            If YY+Y2>Screen Height(WINSCREEN)-1 : YY=Screen Height(WINSCREEN)-Y2-1 : End If
            Exit If OXM<>XX or OYM<>YY or Mouse Key<>1
         Loop
         Box XM,YM To XM+X2,YM+Y2
      End If
      OXM=XM : OYM=YM
   Until Mouse Key<>1
   Gr Writing 1
   '
   If Not(XM=X and YM=Y)

      WIN_SETGFX[NUM]

      WININFO(NUM,0)=0 : Rem temp.disable
      WIN_SELUPDATE[0,X,Y,X2+X,Y2+Y]
      WININFO(NUM,0)=1

      WININFO(NUM,1)=XM
      WININFO(NUM,2)=YM
      WININFO(NUM,3)=XM+X2
      WININFO(NUM,4)=YM+Y2

      '      Proc WIN_UPDATE[0]
      Proc WIN_REDRAW[NUM]

   End If

End Proc
Procedure WIN_CLOSE[NUM]

   X=WININFO(NUM,1)
   Y=WININFO(NUM,2)
   X2=WININFO(NUM,3)
   Y2=WININFO(NUM,4)

   For N=0 To 8
      WININFO(NUM,N)=0
   Next N
   For N=0 To GADCOUNT
      For Q=0 To 4
         WINZONE(NUM,N,Q)=0
      Next Q
   Next N

   Del Block 9000+NUM

   Proc WIN_SELUPDATE[0,X,Y,X2,Y2]

End Proc
Procedure WIN_SIZE[NUM]
   WINSCREEN=WININFO(0,0)
   X=WININFO(NUM,1)
   Y=WININFO(NUM,2)
   X2=WININFO(NUM,3) : OX=X2 : XO2=X2
   Y2=WININFO(NUM,4) : OY=Y2 : YO2=Y2
   XSMIN=WININFO(NUM,5)
   YSMIN=WININFO(NUM,6)
   XSMAX=WININFO(NUM,7)
   YSMAX=WININFO(NUM,8)
   '
   DX=X2-X Screen(X Mouse)
   DY=Y2-Y Screen(Y Mouse)
   Gr Writing 3
   While Mouse Key=1
      X2=X Screen(X Mouse)+DX
      Y2=Y Screen(Y Mouse)+DY
      If X2-X<XSMIN : X2=XSMIN+X : End If
      If Y2-Y<YSMIN : Y2=YSMIN+Y : End If
      If X2-X>XSMAX : X2=XSMAX+X : End If
      If Y2-Y>YSMAX : Y2=YSMAX+Y : End If
      If X2>Screen Width(WINSCREEN)-1 : X2=Screen Width(WINSCREEN)-1 : End If
      If Y2>Screen Height(WINSCREEN)-1 : Y2=Screen Height(WINSCREEN)-1 : End If

      If OX<>X2 or OY<>Y2
         Box X,Y To OX,OY : BXON=0
         OX=X2 : OY=Y2
      End If
      If BXON=0 : Box X,Y To X2,Y2 : BXON=1 : End If
   Wend
   If WININFO(NUM,3)=X2 and WININFO(NUM,4)=Y2
      OUTPUT=0 : FASTUPD=1
   Else
      OUTPUT=1

      If WININFO(NUM,3)<=X2 and WININFO(NUM,4)<=Y2
         FASTUPD=1
      Else FASTUPD=0
      End If

   End If

   WININFO(NUM,3)=X2
   WININFO(NUM,4)=Y2

   If BXON=1 : Box X,Y To X2,Y2 : End If
   Gr Writing 1

   If FASTUPD=0
      WIN_SETGFX[NUM]

      WININFO(NUM,0)=0 : Rem Disable Temporarily
      Proc WIN_SELUPDATE[0,X,Y,XO2,YO2]
      WININFO(NUM,0)=1

      Proc WIN_REDRAW[NUM]
      'Proc WIN_UPDATE[0]

   End If

End Proc[OUTPUT]
Procedure WIN_SELBACKDROP[X,Y,X2,Y2]
   '
   ' Redraw backdrop at specified coords. You could put a screen copy in here
   '  for a graphical backdrop.
   '
   Ink WININFO(0,1)
   Bar X,Y To X2,Y2

End Proc
'
'
Procedure GAD_RAISEBOX_CREATE[X,Y,WIDTH,HEIGHT,STYLE]
   '
   XW=X+WIDTH : YH=Y+HEIGHT : XX=X+1 : YY=Y+1
   XWL=X+WIDTH-1 : YHL=Y+HEIGHT-1

   If STYLE=2 or STYLE=4
      Ink VGREY : Bar XX,YY To XWL,YHL
   End If
   Set Pattern 0
   '
   If STYLE<3
      Ink VWHITE : Polyline XW,Y To X,Y To X,YH
      Ink VBLACK : Polyline XW,YY To XW,YH To XX,YH
   Else
      Ink VWHITE : Polyline XW,Y To X,Y To X,YH
      Polyline XX,YY To XX,YHL
      Ink VBLACK : Polyline XW,Y To XW,YH To XX,YH
      Polyline XWL,YY To XWL,YHL
   End If
   '
End Proc
Procedure GAD_LOWERBOX_CREATE[X,Y,WIDTH,HEIGHT,STYLE]
   '
   XW=X+WIDTH : YH=Y+HEIGHT : XX=X+1 : YY=Y+1
   XWL=X+WIDTH-1 : YHL=Y+HEIGHT-1
   '
   If STYLE=2 or STYLE=4
      Ink VBLUE : Bar XX,YY To XWL,YHL
   End If

   Set Pattern 0
   '
   If STYLE<3
      Ink VBLACK : Polyline XW,Y To X,Y To X,YH
      Ink VWHITE : Polyline XW,YY To XW,YH To XX,YH
   Else
      Ink VBLACK : Polyline XW,Y To X,Y To X,YH
      Polyline XX,YY To XX,YHL
      Ink VWHITE : Polyline XW,Y To XW,YH To XX,YH
      Polyline XWL,YY To XWL,YHL
   End If
   '
End Proc
'
'
'
' Agads2.1 procs ported into Multiwindows. (originals by me)
'    Gadgets are created on the specified window, which must be
'    brought to the front. setgfx must also be called.
'     X and Y values measured from top left of specified window.
'
'    Based on Agads1, used in Turboplus Sceneeditor by C.B Meeks.
'
Procedure GAD_BUTTON_CREATE[WINNUM,GADNUM,X,Y,HEIGHT,NAME$]
   '
   '
   If NAME$="" Then NAME$=" "
   GADTEXT$(WINNUM,GADNUM)=NAME$
   '
   WINZONE(WINNUM,GADNUM,0)=1
   WIN_SET_ZONE[WINNUM,GADNUM,X,Y,(Len(NAME$)*8)+7,HEIGHT]
   '
   ' account for window position
   X=X+WININFO(WINNUM,1)
   Y=Y+WININFO(WINNUM,2)

   GAD_RAISEBOX_CREATE[X,Y,7+Len(NAME$)*8,HEIGHT,4]
   Ink VBLACK,VGREY : Text X+4,Y+(HEIGHT/2)+3,NAME$
End Proc
Procedure GAD_BUTTON_IN[WINNUM,GADNUM]
   '
   NAME$=GADTEXT$(WINNUM,GADNUM)
   '
   X=WINZONE(WINNUM,GADNUM,1)+WININFO(WINNUM,1)
   Y=WINZONE(WINNUM,GADNUM,2)+WININFO(WINNUM,2)
   WIDTH=WINZONE(WINNUM,GADNUM,3)-X+WININFO(WINNUM,1)
   HEIGHT=WINZONE(WINNUM,GADNUM,4)-Y+WININFO(WINNUM,2)
   '
   GAD_LOWERBOX_CREATE[X,Y,WIDTH,HEIGHT,4]
   '
   Ink VBLACK,VBLUE : Text X+4,Y+(HEIGHT/2)+3,NAME$
   '
End Proc
Procedure GAD_BUTTON_OUT[WINNUM,GADNUM]
   '
   NAME$=GADTEXT$(WINNUM,GADNUM)
   '
   X=WINZONE(WINNUM,GADNUM,1)+WININFO(WINNUM,1)
   Y=WINZONE(WINNUM,GADNUM,2)+WININFO(WINNUM,2)
   WIDTH=WINZONE(WINNUM,GADNUM,3)-X+WININFO(WINNUM,1)
   HEIGHT=WINZONE(WINNUM,GADNUM,4)-Y+WININFO(WINNUM,2)
   '
   GAD_RAISEBOX_CREATE[X,Y,WIDTH,HEIGHT,4]
   '
   Ink VBLACK,VGREY : Text X+4,Y+(HEIGHT/2)+3,NAME$
   '
End Proc
'
Procedure GAD_CYCLE_CREATE[WINNUM,GADNUM,X1,Y1,VLENGTH,VSTRING$]

   WINZONE(WINNUM,GADNUM,0)=7
   WINZONE(WINNUM,GADNUM,1)=X1
   WINZONE(WINNUM,GADNUM,2)=Y1
   WINZONE(WINNUM,GADNUM,3)=X1+25+VLENGTH*8
   WINZONE(WINNUM,GADNUM,4)=Y1+12
   GADTEXT$(WINNUM,GADNUM)=""
   GADSTUFF(WINNUM,GADNUM,0)=VLENGTH
   GADSTUFF(WINNUM,GADNUM,1)=1

   X1=X1+WININFO(WINNUM,1)
   Y1=Y1+WININFO(WINNUM,2)

   X2=X1+25+VLENGTH*8
   Y2=Y1+12

   Ink VGREY : Bar X1,Y1 To X2,Y2
   Rem ***** draw the outline
   Add X1,1
   Ink VWHITE,VGREY
    Draw X1,Y1 To X2+1,Y1
    Draw X1,Y1 To X1,Y2
    Draw X1-1,Y1 To X1-1,Y2
   Ink VBLACK
    Draw X1,Y2 To X2,Y2
    Draw X2,Y1+1 To X2,Y2
    Draw X2+1,Y1 To X2+1,Y2
   Rem ***** draw the arrow
   Ink VWHITE
    Draw X1+20,Y1+2 To X1+20,Y2-2
   Ink VBLACK
    Draw X1+19,Y1+2 To X1+19,Y2-2
    Draw X1+6,Y1+2 To X1+13,Y1+2
   Bar X1+13,Y1+3 To X1+14,Y1+6
    Draw X1+11,Y1+4 To X1+16,Y1+4
    Draw X1+12,Y1+5 To X1+15,Y1+5
   Bar X1+5,Y1+3 To X1+6,Y2-3
    Draw X1+6,Y2-2 To X1+13,Y2-2
    Draw X1+13,Y2-3 To X1+14,Y2-3

   GAD_CYCLE_ADDITEM[WINNUM,GADNUM,VSTRING$]
   GAD_CYCLE_SET[WINNUM,GADNUM,1]

End Proc
Procedure GAD_CYCLE_PUSH[WINNUM,GADNUM]

   VLENGTH=GADSTUFF(WINNUM,GADNUM,0)
   VITEM=GADSTUFF(WINNUM,GADNUM,1)
   VSTRING$=GADTEXT$(WINNUM,GADNUM)
   VITEMS=Len(VSTRING$)/VLENGTH
   '
   Add VITEM,1,1 To VITEMS
   GAD_CYCLE_SET[WINNUM,GADNUM,VITEM]
   '
End Proc
Procedure GAD_CYCLE_IN[WINNUM,GADNUM]

   WINX=WININFO(WINNUM,1)
   WINY=WININFO(WINNUM,2)

   X1=WINZONE(WINNUM,GADNUM,1)+WINX
   Y1=WINZONE(WINNUM,GADNUM,2)+WINY
   X2=WINZONE(WINNUM,GADNUM,3)+WINX
   Y2=WINZONE(WINNUM,GADNUM,4)+WINY

   VLENGTH=GADSTUFF(WINNUM,GADNUM,0)
   VITEM=GADSTUFF(WINNUM,GADNUM,1)
   VSTRING$=GADTEXT$(WINNUM,GADNUM)
   VITEMS=Len(VSTRING$)/VLENGTH
   '
   Rem ***** Push the control in
   Ink VBLUE
   Bar X1,Y1 To X2,Y2
   Ink VBLACK,VBLUE
   GAD_CYCLE_SET[WINNUM,GADNUM,VITEM]
    Draw X1,Y1 To X2+1,Y1
    Draw X1,Y1 To X1,Y2
    Draw X1-1,Y1 To X1-1,Y2
   Ink VWHITE,VGREY
    Draw X1,Y2 To X2,Y2
    Draw X2,Y1+1 To X2,Y2
    Draw X2+1,Y1 To X2+1,Y2
   '
   Rem ***** draw the arrow
   Ink VWHITE
    Draw X1+19,Y1+2 To X1+19,Y2-2
   Ink VBLACK
    Draw X1+20,Y1+2 To X1+20,Y2-2
    Draw X1+6,Y1+2 To X1+13,Y1+2
   Bar X1+13,Y1+3 To X1+14,Y1+6
    Draw X1+11,Y1+4 To X1+16,Y1+4
    Draw X1+12,Y1+5 To X1+15,Y1+5
   Bar X1+5,Y1+3 To X1+6,Y2-3
    Draw X1+6,Y2-2 To X1+13,Y2-2
    Draw X1+13,Y2-3 To X1+14,Y2-3
   '
End Proc
Procedure GAD_CYCLE_OUT[WINNUM,GADNUM]

   WINX=WININFO(WINNUM,1)
   WINY=WININFO(WINNUM,2)

   X1=WINZONE(WINNUM,GADNUM,1)+WINX
   Y1=WINZONE(WINNUM,GADNUM,2)+WINY
   X2=WINZONE(WINNUM,GADNUM,3)+WINX
   Y2=WINZONE(WINNUM,GADNUM,4)+WINY

   VLENGTH=GADSTUFF(WINNUM,GADNUM,0)
   VITEM=GADSTUFF(WINNUM,GADNUM,1)
   VSTRING$=GADTEXT$(WINNUM,GADNUM)
   VITEMS=Len(VSTRING$)/VLENGTH
   '
   Ink VGREY
   Bar X1,Y1 To X2,Y2
   Ink VWHITE
    Draw X1,Y1 To X2+1,Y1
    Draw X1,Y1 To X1,Y2
    Draw X1-1,Y1 To X1-1,Y2
   Ink VBLACK
    Draw X1,Y2 To X2,Y2
    Draw X2,Y1+1 To X2,Y2
    Draw X2+1,Y1 To X2+1,Y2
   '
   Rem ***** draw the arrow
   Ink VWHITE
    Draw X1+20,Y1+2 To X1+20,Y2-2
   Ink VBLACK
    Draw X1+19,Y1+2 To X1+19,Y2-2
    Draw X1+6,Y1+2 To X1+13,Y1+2
   Bar X1+13,Y1+3 To X1+14,Y1+6
    Draw X1+11,Y1+4 To X1+16,Y1+4
    Draw X1+12,Y1+5 To X1+15,Y1+5
   Bar X1+5,Y1+3 To X1+6,Y2-3
    Draw X1+6,Y2-2 To X1+13,Y2-2
    Draw X1+13,Y2-3 To X1+14,Y2-3
   '
   GAD_CYCLE_SET[WINNUM,GADNUM,VITEM]
   '
End Proc[VITEM]
Procedure GAD_CYCLE_SET[WINNUM,GADNUM,VITEM]

   X1=WINZONE(WINNUM,GADNUM,1)+WININFO(WINNUM,1)
   Y1=WINZONE(WINNUM,GADNUM,2)+WININFO(WINNUM,2)
   VLENGTH=GADSTUFF(WINNUM,GADNUM,0)
   VSTARTPOS=(VITEM-1)*VLENGTH
   If VITEM>1 : Inc VSTARTPOS : End If
   VSTRING$=Mid$(GADTEXT$(WINNUM,GADNUM),VSTARTPOS,VLENGTH)
   Ink VBLACK
   Text X1+23,Y1+9,VSTRING$
   GADSTUFF(WINNUM,GADNUM,1)=VITEM
End Proc[VITEM]
Procedure GAD_CYCLE_GET[WINNUM,GADNUM]
   VGETID=GADSTUFF(WINNUM,GADNUM,1)
End Proc[VGETID]
Procedure GAD_CYCLE_ADDITEM[WINNUM,GADNUM,VSTRING$]
   VOLDSTRING$=GADTEXT$(WINNUM,GADNUM)
   VLENGTH=GADSTUFF(WINNUM,GADNUM,0)
   If Len(VSTRING$)>VLENGTH
      VSTRING$=Left$(VSTRING$,VLENGTH)
   End If
   VSTRING$=VSTRING$+Space$(VLENGTH-Len(VSTRING$))
   VNEWSTRING$=VOLDSTRING$+VSTRING$
   GADTEXT$(WINNUM,GADNUM)=VNEWSTRING$
End Proc
Procedure GAD_CYCLE_GETTEXT[WINNUM,GADNUM]
   VITEM=GADSTUFF(WINNUM,GADNUM,1)
   VLENGTH=GADSTUFF(WINNUM,GADNUM,0)
   VSTARTPOS=(VITEM-1)*VLENGTH
   If VITEM>1 : Inc VSTARTPOS : End If
   VSTRING$=Mid$(GADTEXT$(WINNUM,GADNUM),VSTARTPOS,VLENGTH)
End Proc[VSTRING$]
'
Procedure GAD_TEXT_CREATE[WINNUM,GADNUM,X1,Y1,VSIZE,VTEXT$,VTYPE]

   X2=VSIZE*8+X1+7
   Y2=Y1+12

   WINZONE(WINNUM,GADNUM,0)=5
   WINZONE(WINNUM,GADNUM,1)=X1
   WINZONE(WINNUM,GADNUM,2)=Y1
   WINZONE(WINNUM,GADNUM,3)=X2
   WINZONE(WINNUM,GADNUM,4)=Y2
   GADSTUFF(WINNUM,GADNUM,0)=VSIZE
   GADSTUFF(WINNUM,GADNUM,1)=VTYPE
   GADTEXT$(WINNUM,GADNUM)=VTEXT$


   X1=X1+WININFO(WINNUM,1) : X2=X2+WININFO(WINNUM,1)
   Y1=Y1+WININFO(WINNUM,2) : Y2=Y2+WININFO(WINNUM,2)

   Ink VGREY : Bar X1,Y1 To X2,Y2

   Rem draw the top
   Ink VWHITE
   Draw X1,Y1 To X2-1,Y1
   Ink VBLACK
   Draw X1+2,Y1+1 To X2-3,Y1+1
   Rem draw right side
   Ink VWHITE
   Draw X1,Y1 To X1,Y2
   Draw X1+1,Y1 To X1+1,Y2-1
   Ink VBLACK
   Draw X1+2,Y1+1 To X1+2,Y2
   Draw X1+3,Y1+1 To X1+3,Y2-2
   Rem draw bottom
   Draw X1+1,Y2 To X2,Y2
   Ink VWHITE
   Draw X1+3,Y2-1 To X2-2,Y2-1
   Rem draw left side
   Draw X2-2,Y1 To X2-2,Y2-1
   Draw X2-3,Y1+2 To X2-3,Y2-1
   Ink VBLACK
   Draw X2-1,Y1+1 To X2-1,Y2
   Draw X2,Y1 To X2,Y2
   GAD_TEXT_SET[WINNUM,GADNUM,VTEXT$,1,0]
End Proc
Procedure GAD_TEXT_SET[WINNUM,GADNUM,VTEXT$,VSCREENPOS,VCURPOS]
   X1=WINZONE(WINNUM,GADNUM,1)+WININFO(WINNUM,1) : Y1=WINZONE(WINNUM,GADNUM,2)+WININFO(WINNUM,2)
   VSCREENSIZE=GADSTUFF(WINNUM,GADNUM,0)
   GADTEXT$(WINNUM,GADNUM)=VTEXT$
   VTEXT$=VTEXT$+" "
   VTEXT$=Mid$(VTEXT$,VSCREENPOS,Min(VSCREENSIZE,Len(VTEXT$)-VSCREENPOS+1))
   Ink VBLACK,VGREY
   Text X1+4,Y1+9,VTEXT$+Space$(VSCREENSIZE-Len(VTEXT$))
   VCURTEXT$=Mid$(VTEXT$,VCURPOS,1)
   If VCURPOS<>0
      Ink VWHITE,VBLUE
      Text X1+4+8*(VCURPOS-1),Y1+9,VCURTEXT$
   End If
End Proc
Procedure GAD_TEXT_INPUT[WINNUM,GADNUM]
   Clear Key

   VFIELD$=GADTEXT$(WINNUM,GADNUM)
   VSCREENSIZE=GADSTUFF(WINNUM,GADNUM,0)
   VTYPE=GADSTUFF(WINNUM,GADNUM,1)
   VSCREENPOS=1

   WINX=WININFO(WINNUM,1)
   WINY=WININFO(WINNUM,2)

   XPOS=WINZONE(WINNUM,GADNUM,1)+WINX

   TX1=WINZONE(WINNUM,GADNUM,1)+WINX
   TY1=WINZONE(WINNUM,GADNUM,2)+WINY
   TX2=WINZONE(WINNUM,GADNUM,3)+WINX
   TY2=WINZONE(WINNUM,GADNUM,4)+WINY
   '
   VMOUSEPOS=(X Screen(X Mouse)+4-XPOS)/8
   If VMOUSEPOS>VSCREENSIZE Then VMOUSEPOS=VSCREENSIZE
   If VMOUSEPOS<1 Then VMOUSEPOS=1
   If VSCREENPOS+VMOUSEPOS>Len(VFIELD$)+1 Then VMOUSEPOS=Len(VFIELD$)+1
   VCURPOS=VMOUSEPOS
   GAD_TEXT_SET[WINNUM,GADNUM,VFIELD$,1,VCURPOS]
   '
   Do
      IN$=Inkey$ : SCAN=Scancode
      XM=X Screen(X Mouse) : YM=Y Screen(Y Mouse)
      '
      '** Right arrow
      If SCAN=78 or ADVANCE=1
         If VCURPOS+VSCREENPOS<=Len(VFIELD$)+1
            If VCURPOS<VSCREENSIZE
               Inc VCURPOS
            Else
               Inc VSCREENPOS
            End If
         End If
         If ADVANCE=1 : ADVANCE=0 : End If
         GAD_TEXT_SET[WINNUM,GADNUM,VFIELD$,VSCREENPOS,VCURPOS]
      End If
      '
      '** Left arrow
      If SCAN=79 or RETREAT=1
         If VCURPOS+VSCREENPOS>2
            If VCURPOS>1
               Dec VCURPOS
            Else
               Dec VSCREENPOS
            End If
         End If
         If RETREAT=1 : RETREAT=0 : End If
         GAD_TEXT_SET[WINNUM,GADNUM,VFIELD$,VSCREENPOS,VCURPOS]
      End If
      '
      '** Text input
      If VTYPE=0
         If Asc(IN$)>31 and Asc(IN$)<127
            VFIELDTEMP$=Left$(VFIELD$,VSCREENPOS+VCURPOS-2)+IN$+Right$(VFIELD$,Len(VFIELD$)-(VSCREENPOS+VCURPOS-2))
            VFIELD$=VFIELDTEMP$
            ADVANCE=1
         End If
      Else
         If Asc(IN$)>47 and Asc(IN$)<58 or Asc(IN$)=46
            VFIELDTEMP$=Left$(VFIELD$,VSCREENPOS+VCURPOS-2)+IN$+Right$(VFIELD$,Len(VFIELD$)-(VSCREENPOS+VCURPOS-2))
            VFIELD$=VFIELDTEMP$
            ADVANCE=1
         End If
      End If
      '
      '** Backspace
      If SCAN=65 and VCURPOS+VSCREENPOS>2
         VFIELDTEMP$=Left$(VFIELD$,VSCREENPOS+VCURPOS-3)+Right$(VFIELD$,Len(VFIELD$)-(VSCREENPOS+VCURPOS-2))
         VFIELD$=VFIELDTEMP$
      If VSCREENPOS=1 : RETREAT=1 : Else Dec VSCREENPOS : GAD_TEXT_SET[WINNUM,GADNUM,VFIELD$,VSCREENPOS,VCURPOS] : End If
      End If
      '
      '** Delete
      If SCAN=70 and VCURPOS+VSCREENPOS<=Len(VFIELD$)+1
         VFIELDTEMP$=Left$(VFIELD$,VSCREENPOS+VCURPOS-2)+Right$(VFIELD$,Len(VFIELD$)-(VSCREENPOS+VCURPOS-3)-2)
         VFIELD$=VFIELDTEMP$
         GAD_TEXT_SET[WINNUM,GADNUM,VFIELD$,VSCREENPOS,VCURPOS]
         '
      End If
      '
      '** Mouse clicking
      Exit If SCAN=68 or SCAN=94 or SCAN=74
      If Mouse Key=1
         If XM<TX1 or YM<TY1 or XM>TX2 or YM>TY2 : Exit : End If
         If XM>TX1 or YM>TY1 or XM<TX2 or YM<TY2
            VMOUSEPOS=(X Screen(X Mouse)+4-XPOS)/8
            If VMOUSEPOS>VSCREENSIZE : VMOUSEPOS=VSCREENSIZE : End If
            If VMOUSEPOS<1 : VMOUSEPOS=1 : End If
            If VSCREENPOS+VMOUSEPOS>Len(VFIELD$)+1 : VMOUSEPOS=(Len(VFIELD$)+1)-(VSCREENPOS-1) : End If
            VCURPOS=VMOUSEPOS
            GAD_TEXT_SET[WINNUM,GADNUM,VFIELD$,VSCREENPOS,VCURPOS]
            Repeat : Until Mouse Key=0
         End If
      End If
   Loop
   GAD_TEXT_SET[WINNUM,GADNUM,VFIELD$,1,0]
End Proc[VFIELD$]
Procedure GAD_TEXT_GET[WINNUM,GADNUM]
   VTEXT$=GADTEXT$(WINNUM,GADNUM)
End Proc[VTEXT$]
Procedure GAD_TEXT_NEXT[WINNUM,GADNUM]
   VNEXTSTRINGGAD=GADNUM
   Do
      Add VNEXTSTRINGGAD,1,1 To GADCOUNT
      GADTYPE[WINNUM,VNEXTSTRINGGAD]
      VTYPE=Param
      Exit If VTYPE=5
   Loop
End Proc[VNEXTSTRINGGAD]
Procedure GAD_TEXT_PREV[WINNUM,GADNUM]
   VPREVSTRINGGAD=GADNUM
   Do
      Add VPREVSTRINGGAD,-1,1 To GADCOUNT
      GADTYPE[WINNUM,VPREVSTRINGGAD]
      VTYPE=Param
      Exit If VTYPE=5
   Loop
End Proc[VPREVSTRINGGAD]

Procedure GAD_DISPLAY_CREATE[WINNUM,GADNUM,X1,Y1,VLENGTH,VTEXT$]
   X2=X1+VLENGTH*8+7
   Y2=Y1+12

   WINZONE(WINNUM,GADNUM,0)=6
   WINZONE(WINNUM,GADNUM,1)=X1
   WINZONE(WINNUM,GADNUM,2)=Y1
   WINZONE(WINNUM,GADNUM,3)=X2
   WINZONE(WINNUM,GADNUM,4)=Y2
   GADSTUFF(WINNUM,GADNUM,0)=VLENGTH
   GADTEXT$(WINNUM,GADNUM)=VTEXT$

   X1=X1+WININFO(WINNUM,1) : X2=X2+WININFO(WINNUM,1)
   Y1=Y1+WININFO(WINNUM,2) : Y2=Y2+WININFO(WINNUM,2)

   Ink VGREY : Bar X1,Y1 To X2,Y2
   VTEXTPRINT$=Left$(VTEXT$,Min(VLENGTH,Len(VTEXT$)))
   Rem ***** draw the gadget
   Ink VBLACK
   Draw X1,Y1 To X2-1,Y1
   Bar X1,Y1 To X1+1,Y2-1
   Plot X1,Y2
   Ink VWHITE
   Draw X1+1,Y2 To X2,Y2
   Bar X2-1,Y1+1 To X2,Y2
   Plot X2,Y1
   Rem ***** fill in the text
   Ink VBLACK,VGREY
   Text X1+4,Y1+9,VTEXTPRINT$

End Proc
Procedure GAD_DISPLAY_SET[WINNUM,GADNUM,VTEXT$]

   WINX=WININFO(WINNUM,1)
   WINY=WININFO(WINNUM,2)

   X1=WINZONE(WINNUM,GADNUM,1)+WINX
   Y1=WINZONE(WINNUM,GADNUM,2)+WINY
   X2=WINZONE(WINNUM,GADNUM,3)+WINX
   Y2=WINZONE(WINNUM,GADNUM,4)+WINY

   VDISPLAYLEN=GADSTUFF(WINNUM,GADNUM,0)
   Rem ***** clear the display
   Ink VGREY
   Bar X1+2,Y1+1 To X2-2,Y2-1
   VTEXTDISPLAY$=Left$(VTEXT$,Min(VDISPLAYLEN,Len(VTEXT$)))
   Ink VBLACK,VGREY
   Text X1+4,Y1+9,VTEXTDISPLAY$
   GADTEXT$(WINNUM,GADNUM)=VTEXT$
End Proc
Procedure GAD_DISPLAY_GET[WINNUM,GADNUM]
   GADTEXT$=GADTEXT$(WINNUM,GADNUM)
End Proc[GADTEXT$]
'
Procedure GAD_CHECKBOX_CREATE[WINNUM,GADNUM,X,Y]
   '
   WINZONE(WINNUM,GADNUM,0)=17
   WINZONE(WINNUM,GADNUM,1)=X
   WINZONE(WINNUM,GADNUM,2)=Y
   WINZONE(WINNUM,GADNUM,3)=X+25
   WINZONE(WINNUM,GADNUM,4)=Y+10
   GADSTUFF(WINNUM,GADNUM,1)=0
   '
   '
   X=X+WININFO(WINNUM,1)
   Y=Y+WININFO(WINNUM,2)
   '
   Ink VGREY
   Bar X,Y To X+25,Y+10
   '
   Ink VBLACK
   Draw X+25,Y To X+25,Y+10
   Draw X+25,Y+10 To X,Y+10
   Draw X+24,Y+1 To X+24,Y+10
   Ink VWHITE
   Draw X,Y To X+24,Y
   Draw X,Y To X,Y+10
   Draw X+1,Y To X+1,Y+9
   '
End Proc
Procedure GAD_CHECKBOX_TICK[WINNUM,GADNUM]
   X=WINZONE(WINNUM,GADNUM,1)+WININFO(WINNUM,1)
   Y=WINZONE(WINNUM,GADNUM,2)+WININFO(WINNUM,2)
   TICK=GADSTUFF(WINNUM,GADNUM,1)
   '
   '
   Restore HELLO
   If TICK=1 Then F=VGREY : NUMB=0 : Else F=VBLACK : NUMB=1
   For N=1 To 7
      For T=1 To 14
         Read A : If A=1 Then Plot T+X+6,N+Y+1,F
      Next T
   Next N
   '
   HELLO:
   Data 0,0,0,0,0,0,0,0,0,0,1,1,1,0
   Data 0,0,0,0,0,0,0,0,0,1,1,0,0,0
   Data 0,0,0,0,0,0,0,0,1,1,0,0,0,0
   Data 1,1,1,0,0,0,0,1,1,0,0,0,0,0
   Data 0,1,1,1,0,0,1,1,0,0,0,0,0,0
   Data 0,0,1,1,1,1,1,0,0,0,0,0,0,0
   Data 0,0,0,1,1,1,0,0,0,0,0,0,0,0
   '
   If NUMB=1 Then GADSTUFF(WINNUM,GADNUM,1)=1 Else GADSTUFF(WINNUM,GADNUM,1)=0
   '
   Repeat : Until Mouse Key=0
End Proc[NUMB]
'
Procedure GADTYPE[WINNUM,GADNUM]
   TYPE=WINZONE(WINNUM,GADNUM,0)
End Proc[TYPE]
'
Procedure GAD_RADIOBUT_CREATE[WINNUM,GADNUM,X,Y,GROUPNUM]
   '
   If GROUPNUM=0 Then Bell 10 : End : Rem ** NO GROUPNUM 0 ! **
   '
   '
   WINZONE(WINNUM,GADNUM,0)=32
   WINZONE(WINNUM,GADNUM,1)=X
   WINZONE(WINNUM,GADNUM,2)=Y
   WINZONE(WINNUM,GADNUM,3)=X+18
   WINZONE(WINNUM,GADNUM,4)=Y+8
   GADSTUFF(WINNUM,GADNUM,1)=GROUPNUM
   If GADRADIO(WINNUM,GROUPNUM)>0
      GADRADIO(WINNUM,0)=1 : GAD_RADIOBUT_PUSH[WINNUM,GADNUM] : GADRADIO(WINNUM,0)=0
   Else
      GAD_RADIOBUT_IN[WINNUM,GADNUM]
      GADRADIO(WINNUM,GROUPNUM)=GADNUM
   End If
   '
End Proc
Procedure GAD_RADIOBUT_IN[WINNUM,GADNUM]
   '
   '
   X=WINZONE(WINNUM,GADNUM,1)+WININFO(WINNUM,1)
   Y=WINZONE(WINNUM,GADNUM,2)+WININFO(WINNUM,2)
   '
   Ink VGREY
   Bar X+3,Y+1 To X+15,Y+7
   Ink VBLACK
   Draw X+3,Y To X+15,Y
   Draw X+2,Y+1 To X+3,Y+1
   Draw X+1,Y+2 To X+1,Y+6
   Draw X+2,Y+2 To X+2,Y+6
   Draw X+2,Y+7 To X+3,Y+7
   Ink VWHITE
   Draw X+3,Y+8 To X+15,Y+8
   Draw X+15,Y+7 To X+16,Y+7
   Draw X+16,Y+2 To X+16,Y+6
   Draw X+17,Y+2 To X+17,Y+6
   Draw X+15,Y+1 To X+16,Y+1
   Ink VBLUE
   Bar X+7,Y+2 To X+11,Y+6
   Draw X+6,Y+2 To X+6,Y+6
   Draw X+5,Y+3 To X+5,Y+5
   Draw X+12,Y+2 To X+12,Y+6
   Draw X+13,Y+3 To X+13,Y+5
   '
End Proc
Procedure GAD_RADIOBUT_OUT[WINNUM,GADNUM]
   '
   '
   X=WINZONE(WINNUM,GADNUM,1)+WININFO(WINNUM,1)
   Y=WINZONE(WINNUM,GADNUM,2)+WININFO(WINNUM,2)
   '
   Ink VGREY
   Bar X+3,Y+1 To X+15,Y+7
   Ink VWHITE
   Draw X+3,Y To X+15,Y
   Draw X+2,Y+1 To X+3,Y+1
   Draw X+1,Y+2 To X+1,Y+6
   Draw X+2,Y+2 To X+2,Y+6
   Draw X+2,Y+7 To X+3,Y+7
   Ink VBLACK
   Draw X+3,Y+8 To X+15,Y+8
   Draw X+15,Y+7 To X+16,Y+7
   Draw X+16,Y+2 To X+16,Y+6
   Draw X+17,Y+2 To X+17,Y+6
   Draw X+15,Y+1 To X+16,Y+1
   '
End Proc
Procedure GAD_RADIOBUT_PUSH[WINNUM,GADNUM]
   GROUPNUM=GADSTUFF(WINNUM,GADNUM,1)
   PUSHED=GADRADIO(WINNUM,GROUPNUM)
   '
   GAD_RADIOBUT_IN[WINNUM,GADNUM]
   GADRADIO(WINNUM,GROUPNUM)=GADNUM
   If GADNUM<>PUSHED
      GAD_RADIOBUT_OUT[WINNUM,PUSHED]
   End If
   '
   If GADRADIO(WINNUM,0)=0 Then Repeat : Until Mouse Key=0
End Proc
'
Procedure GAD_SLIDER_CREATE[WINNUM,GADNUM,X,Y,XSIZ,YSIZ,NUMSTEPS,PAGESIZE]

   If NUMSTEPS<1 : NUMSTEPS=1 : PAGESIZE=1 : End If
   If PAGESIZE>NUMSTEPS : PAGESIZE=NUMSTEPS : End If

   WINZONE(WINNUM,GADNUM,0)=13
   WINZONE(WINNUM,GADNUM,1)=X
   WINZONE(WINNUM,GADNUM,2)=Y+1
   WINZONE(WINNUM,GADNUM,3)=X+XSIZ-1
   WINZONE(WINNUM,GADNUM,4)=Y+YSIZ-2
   '
   Add X,WININFO(WINNUM,1)
   Add Y,WININFO(WINNUM,2)
   '
   GADSTUFF(WINNUM,GADNUM,1)=NUMSTEPS-PAGESIZE+1
   GADSTUFF(WINNUM,GADNUM,2)=PAGESIZE

   GADRADIO(WINNUM,GADNUM)=0

   PADDLESIZE=(PAGESIZE*(YSIZ-2))/NUMSTEPS
   If PADDLESIZE<6 : PADDLESIZE=6 : End If
   GADSTUFF(WINNUM,GADNUM,3)=PADDLESIZE

   AREA=YSIZ-2-PADDLESIZE
   GADSTUFF(WINNUM,GADNUM,4)=AREA
   '
   GADSTUFF(WINNUM,GADNUM,5)=0
   Ink VBLACK,VBLUE : Set Pattern 2
   Bar X,Y To X+XSIZ-1,Y+YSIZ-1 : Set Pattern 0

   '   GAD_LOWERBOX_CREATE[X,Y,XSIZ,YSIZ,1]
   Ink VBLACK : Polyline X+XSIZ-1,Y To X,Y To X,Y+YSIZ-1
   Ink VWHITE : Polyline X+XSIZ-1,Y+1 To X+XSIZ-1,Y+YSIZ-1 To X+1,Y+YSIZ-1
   '   GAD_RAISEBOX_CREATE[X+1,Y+1,XSIZ-2,PADDLESIZE,2]
   Ink VGREY : Bar X+2,Y+2 To X+XSIZ-2,Y+PADDLESIZE
   Ink VWHITE : Polyline X+XSIZ-2,Y+1 To X+1,Y+1 To X+1,Y+PADDLESIZE
   Ink VBLACK : Polyline X+XSIZ-2,Y+2 To X+XSIZ-2,Y+PADDLESIZE To X+2,Y+PADDLESIZE

   SEP=Y+(PADDLESIZE/2)
   Ink VWHITE : Draw X+7,SEP To X+XSIZ-8,SEP
   Ink VBLACK : Draw X+7,SEP+1 To X+XSIZ-8,SEP+1

   GADSTUFF(WINNUM,GADNUM,6)=0
   '   GAD_SLIDER_UPDATE[GADNUM,10]

End Proc
Procedure GAD_SLIDER_UPDATE[WINNUM,GADNUM,STP]

   OSTP=GADSTUFF(WINNUM,GADNUM,5)
   If OSTP<>STP

      X=WINZONE(WINNUM,GADNUM,1)+1
      X2=WINZONE(WINNUM,GADNUM,3)-1
      Y=WINZONE(WINNUM,GADNUM,2)

      Add X,WININFO(WINNUM,1)
      Add X2,WININFO(WINNUM,1)
      Add Y,WININFO(WINNUM,2)

      AREA=GADSTUFF(WINNUM,GADNUM,4)
      NUMSTEPS=GADSTUFF(WINNUM,GADNUM,1)
      PADSIZE=GADSTUFF(WINNUM,GADNUM,3)

      SPOS=Y+(AREA*STP)/(NUMSTEPS-1)
      OPOS=Y+(AREA*OSTP)/(NUMSTEPS-1)
      If OPOS<>SPOS

         HP=(PADSIZE/2) : SEP=OPOS+HP-1
         Ink VGREY : Box X+6,SEP To X2-6,SEP+1

         If SPOS>OPOS
            Ink VGREY : Bar X,OPOS+PADSIZE-2 To X2,SPOS+PADSIZE-1
            Ink VBLACK,VBLUE : Set Pattern 2
            Bar X,OPOS To X2,SPOS : Set Pattern 0
         Else
            Ink VGREY : Bar X,SPOS To X2,OPOS+1
            Ink VBLACK,VBLUE : Set Pattern 2
            Bar X,SPOS+PADSIZE-1 To X2,OPOS+PADSIZE-1 : Set Pattern 0
         End If
         '         GAD_RAISEBOX_CREATE[X,SPOS,X2-X+1,PADSIZE,1]
         XL=X2-X : YL=SPOS+PADSIZE-1
         Ink VWHITE : Polyline X+XL,SPOS To X,SPOS To X,YL
         Ink VBLACK : Polyline X+XL,SPOS+1 To X+XL,YL To X+1,YL

         SEP=SPOS+HP-1
         Ink VWHITE : Draw X+6,SEP To X2-6,SEP
         Ink VBLACK : Draw X+6,SEP+1 To X2-6,SEP+1

      End If
      GADSTUFF(WINNUM,GADNUM,5)=STP
      GADSTUFF(WINNUM,GADNUM,6)=SPOS-Y
   End If
End Proc
Procedure GAD_SLIDER_MOUSE_UPDATE[WINNUM,GADNUM]

   NUMSTEPS=GADSTUFF(WINNUM,GADNUM,1)
   STP=GADSTUFF(WINNUM,GADNUM,5)
   If NUMSTEPS>1

      X=WINZONE(WINNUM,GADNUM,1)+1
      X2=WINZONE(WINNUM,GADNUM,3)-1
      Y=WINZONE(WINNUM,GADNUM,2)

   Add X,WININFO(WINNUM,1)
   Add X2,WININFO(WINNUM,1)
   Add Y,WININFO(WINNUM,2)

      PAGESIZE=GADSTUFF(WINNUM,GADNUM,2)
      AREA=GADSTUFF(WINNUM,GADNUM,4)
      PADSIZE=GADSTUFF(WINNUM,GADNUM,3)

      OPOS=GADSTUFF(WINNUM,GADNUM,6)+Y
      SPOS=Y Screen(Y Mouse)

      If SPOS<OPOS and GADRADIO(WINNUM,GADNUM)=0

         Add STP,1-PAGESIZE
         If STP<0 : STP=0 : End If
         SPOS=Y+(AREA*STP)/(NUMSTEPS-1)
         Repeat : Until Mouse Key=0

      Else If SPOS>OPOS+PADSIZE-1 and GADRADIO(WINNUM,GADNUM)=0

         Add STP,PAGESIZE-1
         If STP>NUMSTEPS-1 : STP=NUMSTEPS-1 : End If
         SPOS=Y+(AREA*STP)/(NUMSTEPS-1)
         Repeat : Until Mouse Key=0

      Else
         If GADRADIO(WINNUM,GADNUM)=0
            GAP=SPOS-OPOS
         Else
            GAP=GADRADIO(WINNUM,GADNUM)-1
         End If
         '
         Do
            SPOS=Y Screen(Y Mouse)-GAP
            If SPOS>Y+AREA
               SPOS=Y+AREA
            Else If SPOS<Y
               SPOS=Y
            End If
            If SPOS<>OPOS

               GADRADIO(WINNUM,GADNUM)=GAP+1
               STP=((SPOS-Y)*NUMSTEPS)/AREA
               If STP>NUMSTEPS-1 : STP=NUMSTEPS-1 : End If
               Exit

            Else If Mouse Key=0
               If GADRADIO(WINNUM,GADNUM)=0
                  If GAP>(PADSIZE/2)-1
                     Inc STP
                     If STP>(NUMSTEPS-1)
                        STP=(NUMSTEPS-1)
                     End If
                  Else
                     Dec STP
                     If STP<0
                        STP=0
                     End If
                  End If
                  SPOS=Y+(AREA*STP)/(NUMSTEPS-1)
                  Y Mouse=Y Hard(SPOS+GAP)
               End If
               GADRADIO(WINNUM,GADNUM)=0
               Exit
            End If
         Loop

      End If

      If SPOS<>OPOS
         HP=(PADSIZE/2) : SEP=OPOS+HP-1
         Ink VGREY : Box X+6,SEP To X2-6,SEP+1
         If SPOS>OPOS
            Ink VGREY : Bar X,OPOS+PADSIZE-2 To X2,SPOS+PADSIZE-1
            Ink VBLACK,VBLUE : Set Pattern 2
            Bar X,OPOS To X2,SPOS : Set Pattern 0
         Else
            Ink VGREY : Bar X,SPOS To X2,OPOS+1
            Ink VBLACK,VBLUE : Set Pattern 2
            Bar X,SPOS+PADSIZE-1 To X2,OPOS+PADSIZE-1 : Set Pattern 0
         End If
         '      GAD_RAISEBOX_CREATE[X,SPOS,X2-X+1,PADSIZE,1]
         'XL=X2-X
         '   Ink VWHITE : Polyline X+XL,SPOS To X,SPOS To X,SPOS+PADSIZE-1
         '   Ink VBLACK : Polyline X+XL,SPOS+1 To X+XL,SPOS+PADSIZE-1 To X+1,SPOS+PADSIZE-1

         XL=X2-X : YL=SPOS+PADSIZE-1
         Ink VWHITE : Polyline X+XL,SPOS To X,SPOS To X,YL
         Ink VBLACK : Polyline X+XL,SPOS+1 To X+XL,YL To X+1,YL

         SEP=SPOS+HP-1
         Ink VWHITE : Draw X+6,SEP To X2-6,SEP
         Ink VBLACK : Draw X+6,SEP+1 To X2-6,SEP+1

      End If

      GADSTUFF(WINNUM,GADNUM,5)=STP
      GADSTUFF(WINNUM,GADNUM,6)=SPOS-Y
   End If
End Proc[STP]
'  Horizontal sliders have a small issue in hires, due to the
'   low res pointer. Not a bug! - too insignificant to be worth
'   fixing!
Procedure GAD_HSLIDER_CREATE[WINNUM,GADNUM,X,Y,XSIZ,YSIZ,NUMSTEPS,PAGESIZE]

   If NUMSTEPS<1 : NUMSTEPS=1 : PAGESIZE=1 : End If
   If PAGESIZE>NUMSTEPS : PAGESIZE=NUMSTEPS : End If

   WINZONE(WINNUM,GADNUM,0)=15
   WINZONE(WINNUM,GADNUM,1)=X+1
   WINZONE(WINNUM,GADNUM,2)=Y
   WINZONE(WINNUM,GADNUM,3)=X+XSIZ-2
   WINZONE(WINNUM,GADNUM,4)=Y+YSIZ-1
   '
   Add X,WININFO(WINNUM,1)
   Add Y,WININFO(WINNUM,2)
'
   GADSTUFF(WINNUM,GADNUM,1)=NUMSTEPS-PAGESIZE+1
   GADSTUFF(WINNUM,GADNUM,2)=PAGESIZE

   GADRADIO(WINNUM,GADNUM)=0

   PADDLESIZE=(PAGESIZE*(XSIZ-2))/NUMSTEPS
   If PADDLESIZE<6 : PADDLESIZE=6 : End If
   GADSTUFF(WINNUM,GADNUM,3)=PADDLESIZE

   AREA=XSIZ-2-PADDLESIZE
   GADSTUFF(WINNUM,GADNUM,4)=AREA
   '
   GADSTUFF(WINNUM,GADNUM,5)=0
   Ink VBLACK,VBLUE : Set Pattern 2
   Bar X,Y To X+XSIZ-1,Y+YSIZ-1 : Set Pattern 0

   '   GAD_LOWERBOX_CREATE[X,Y,XSIZ,YSIZ,1]
   Ink VBLACK : Polyline X+XSIZ-1,Y To X,Y To X,Y+YSIZ-1
   Ink VWHITE : Polyline X+XSIZ-1,Y+1 To X+XSIZ-1,Y+YSIZ-1 To X+1,Y+YSIZ-1
   '   GAD_RAISEBOX_CREATE[X+1,Y+1,XSIZ-2,PADDLESIZE,2]
   Ink VGREY : Bar X+2,Y+2 To X+PADDLESIZE,Y+YSIZ-2
   Ink VWHITE : Polyline X+1,Y+YSIZ-2 To X+1,Y+1 To X+PADDLESIZE,Y+1
   Ink VBLACK : Polyline X+2,Y+YSIZ-2 To X+PADDLESIZE,Y+YSIZ-2 To X+PADDLESIZE,Y+2

   SEP=X+(PADDLESIZE/2)
   Ink VWHITE : Draw SEP,Y+7 To SEP,Y+YSIZ-8
   Ink VBLACK : Draw SEP+1,Y+7 To SEP+1,Y+YSIZ-8

   GADSTUFF(WINNUM,GADNUM,6)=0
   '   GAD_SLIDER_UPDATE[GADNUM,10]

End Proc
Procedure GAD_HSLIDER_UPDATE[WINNUM,GADNUM,STP]

   OSTP=GADSTUFF(WINNUM,GADNUM,5)
   If OSTP<>STP

      X=WINZONE(WINNUM,GADNUM,1)
      Y=WINZONE(WINNUM,GADNUM,2)+1
      Y2=WINZONE(WINNUM,GADNUM,4)-1

   Add X,WININFO(WINNUM,1)
   Add Y,WININFO(WINNUM,2)
   Add Y2,WININFO(WINNUM,2)

      AREA=GADSTUFF(WINNUM,GADNUM,4)
      NUMSTEPS=GADSTUFF(WINNUM,GADNUM,1)
      PADSIZE=GADSTUFF(WINNUM,GADNUM,3)

      SPOS=X+(AREA*STP)/(NUMSTEPS-1)
      OPOS=X+(AREA*OSTP)/(NUMSTEPS-1)
      If OPOS<>SPOS

         HP=(PADSIZE/2) : SEP=OPOS+HP-1
         Ink VGREY : Box SEP,Y+6 To SEP+1,Y2-6

         If SPOS>OPOS
            Ink VGREY : Bar OPOS+PADSIZE-2,Y To SPOS+PADSIZE-1,Y2
            Ink VBLACK,VBLUE : Set Pattern 2
            Bar OPOS,Y To SPOS,Y2 : Set Pattern 0
         Else
            Ink VGREY : Bar SPOS,Y To OPOS+1,Y2
            Ink VBLACK,VBLUE : Set Pattern 2
            Bar SPOS+PADSIZE-1,Y To OPOS+PADSIZE-1,Y2 : Set Pattern 0
         End If
         '         GAD_RAISEBOX_CREATE[X,SPOS,X2-X+1,PADSIZE,1]
         YL=Y2-Y : XL=SPOS+PADSIZE-1
         Ink VWHITE : Polyline SPOS,Y+YL To SPOS,Y To XL,Y
         Ink VBLACK : Polyline SPOS+1,Y+YL To XL,Y+YL To XL,Y+1

         SEP=SPOS+HP-1
         Ink VWHITE : Draw SEP,Y+6 To SEP,Y2-6
         Ink VBLACK : Draw SEP+1,Y+6 To SEP+1,Y2-6

      End If
      GADSTUFF(WINNUM,GADNUM,5)=STP
      GADSTUFF(WINNUM,GADNUM,6)=SPOS-X
   End If
End Proc
Procedure GAD_HSLIDER_MOUSE_UPDATE[WINNUM,GADNUM]

   NUMSTEPS=GADSTUFF(WINNUM,GADNUM,1)
   STP=GADSTUFF(WINNUM,GADNUM,5)
   If NUMSTEPS>1

      X=WINZONE(WINNUM,GADNUM,1)
      Y=WINZONE(WINNUM,GADNUM,2)+1
      Y2=WINZONE(WINNUM,GADNUM,4)-1

   Add X,WININFO(WINNUM,1)
   Add Y,WININFO(WINNUM,2)
   Add Y2,WININFO(WINNUM,2)

      PAGESIZE=GADSTUFF(WINNUM,GADNUM,2)
      AREA=GADSTUFF(WINNUM,GADNUM,4)
      PADSIZE=GADSTUFF(WINNUM,GADNUM,3)

      OPOS=GADSTUFF(WINNUM,GADNUM,6)+X
      SPOS=X Screen(X Mouse)

      If SPOS<OPOS and GADRADIO(WINNUM,GADNUM)=0

         Add STP,1-PAGESIZE
         If STP<0 : STP=0 : End If
         SPOS=X+(AREA*STP)/(NUMSTEPS-1)
         Repeat : Until Mouse Key=0

      Else If SPOS>OPOS+PADSIZE-1 and GADRADIO(WINNUM,GADNUM)=0

         Add STP,PAGESIZE-1
         If STP>NUMSTEPS-1 : STP=NUMSTEPS-1 : End If
         SPOS=X+(AREA*STP)/(NUMSTEPS-1)
         Repeat : Until Mouse Key=0

      Else
         If GADRADIO(WINNUM,GADNUM)=0
            GAP=SPOS-OPOS
         Else
            GAP=GADRADIO(WINNUM,GADNUM)-1
         End If
         '
         Do
            SPOS=X Screen(X Mouse)-GAP
            If SPOS>X+AREA
               SPOS=X+AREA
            Else If SPOS<X
               SPOS=X
            End If
            If SPOS<>OPOS

               GADRADIO(WINNUM,GADNUM)=GAP+1
               STP=((SPOS-X)*NUMSTEPS)/AREA
               If STP>NUMSTEPS-1 : STP=NUMSTEPS-1 : End If
               Exit

            Else If Mouse Key=0
               If GADRADIO(WINNUM,GADNUM)=0
                  If GAP>(PADSIZE/2)-1
                     Inc STP
                     If STP>(NUMSTEPS-1)
                        STP=(NUMSTEPS-1)
                     End If
                  Else
                     Dec STP
                     If STP<0
                        STP=0
                     End If
                  End If
                  SPOS=X+(AREA*STP)/(NUMSTEPS-1)
                  X Mouse=X Hard(SPOS+GAP)
               End If
               GADRADIO(WINNUM,GADNUM)=0
               Exit
            End If
         Loop

      End If

      If OPOS<>SPOS

         HP=(PADSIZE/2) : SEP=OPOS+HP-1
         Ink VGREY : Box SEP,Y+6 To SEP+1,Y2-6

         If SPOS>OPOS
            Ink VGREY : Bar OPOS+PADSIZE-2,Y To SPOS+PADSIZE-1,Y2
            Ink VBLACK,VBLUE : Set Pattern 2
            Bar OPOS,Y To SPOS,Y2 : Set Pattern 0
         Else
            Ink VGREY : Bar SPOS,Y To OPOS+1,Y2
            Ink VBLACK,VBLUE : Set Pattern 2
            Bar SPOS+PADSIZE-1,Y To OPOS+PADSIZE-1,Y2 : Set Pattern 0
         End If
         '         GAD_RAISEBOX_CREATE[X,SPOS,X2-X+1,PADSIZE,1]
         YL=Y2-Y : XL=SPOS+PADSIZE-1
         Ink VWHITE : Polyline SPOS,Y+YL To SPOS,Y To XL,Y
         Ink VBLACK : Polyline SPOS+1,Y+YL To XL,Y+YL To XL,Y+1

         SEP=SPOS+HP-1
         Ink VWHITE : Draw SEP,Y+6 To SEP,Y2-6
         Ink VBLACK : Draw SEP+1,Y+6 To SEP+1,Y2-6

      End If

      GADSTUFF(WINNUM,GADNUM,5)=STP
      GADSTUFF(WINNUM,GADNUM,6)=SPOS-X
   End If
End Proc[STP]
'
' Below uses an old system, used in my old sliders. Use scrolloff
'  to deactivate the buttons after they have been used.
Procedure GAD_SCROLLBUT_CREATE[WINNUM,GADNUM,X,Y]
   '
   WINZONE(WINNUM,GADNUM,0)=34
   WINZONE(WINNUM,GADNUM,1)=X
   WINZONE(WINNUM,GADNUM,2)=Y
   WINZONE(WINNUM,GADNUM,3)=X+34
   WINZONE(WINNUM,GADNUM,4)=Y+12
   '
   X=X+WININFO(WINNUM,1)
   Y=Y+WININFO(WINNUM,2)

   GAD_RAISEBOX_CREATE[X,Y,15,12,4]
   GAD_RAISEBOX_CREATE[X+17,Y,15,12,4]
   '
   Ink VBLACK,VGREY
   Text X+4,Y+9,"<"
   Text X+21,Y+9,">"
   '
End Proc
Procedure GAD_SCROLLBUT_UPDATE[WINNUM,GADNUM]
   '
   WINX=WININFO(WINNUM,1)
   WINY=WININFO(WINNUM,2)
   X=WINZONE(WINNUM,GADNUM,1)+WINX
   Y=WINZONE(WINNUM,GADNUM,2)+WINY
   '
   If GADSTUFF(WINNUM,GADNUM,0)<>1
      If X Screen(X Mouse)<X+15
         If GADSTUFF(WINNUM,GADNUM,0)=2
            GAD_SCROLLBUT_OUT[WINNUM,GADNUM,2]
         End If
         GAD_LOWERBOX_CREATE[X,Y,15,12,4]
         Ink VWHITE,VBLUE
         Text X+4,Y+9,"<"
         GADSTUFF(WINNUM,GADNUM,0)=1
      End If
      Inc GADSTUFF(WINNUM,GADNUM,1)
   End If
   If GADSTUFF(WINNUM,GADNUM,0)<>2
      If X Screen(X Mouse)=>X+15
         If GADSTUFF(WINNUM,GADNUM,0)=1
            GAD_SCROLLBUT_OUT[WINNUM,GADNUM,1]
         End If
         GAD_LOWERBOX_CREATE[X+17,Y,15,12,4]
         Ink VWHITE,VBLUE
         Text X+21,Y+9,">"
         GADSTUFF(WINNUM,GADNUM,0)=2
      End If
      Dec GADSTUFF(WINNUM,GADNUM,1)
   End If
   '
   '
   FIN:
End Proc[GADSTUFF(WINNUM,GADNUM,1)]
Procedure GAD_SCROLLOFF[WINNUM,GADNUM]
   GAD_SCROLLBUT_OUT[WINNUM,GADNUM,GADSTUFF(WINNUM,GADNUM,0)]
   GADSTUFF(WINNUM,GADNUM,0)=0
End Proc
Procedure GAD_SCROLLBUT_OUT[WINNUM,GADNUM,BUTTON]
   '
   WINX=WININFO(WINNUM,1)
   WINY=WININFO(WINNUM,2)
   X=WINZONE(WINNUM,GADNUM,1)+WINX
   Y=WINZONE(WINNUM,GADNUM,2)+WINY
   If BUTTON=1
      GAD_RAISEBOX_CREATE[X,Y,15,12,4]
      Ink VBLACK,VGREY
      Text X+4,Y+9,"<"
   Else If BUTTON=2
      GAD_RAISEBOX_CREATE[X+17,Y,15,12,4]
      Ink VBLACK,VGREY
      Text X+21,Y+9,">"
   End If
End Proc
Procedure GAD_SCROLLBUT_SET[WINNUM,GADNUM,SVALUE]
   GADSTUFF(WINNUM,GADNUM,1)=SVALUE
End Proc[SVALUE]
'
Procedure GAD_SBUT_CREATE[WINNUM,GADNUM,X,Y,WIDTH,HEIGHT,STYLE]
   '
   If STYLE>2 Then Dec WIDTH
   '
   WINZONE(WINNUM,GADNUM,0)=20
   WINZONE(WINNUM,GADNUM,1)=X
   WINZONE(WINNUM,GADNUM,2)=Y
   WINZONE(WINNUM,GADNUM,3)=X+WIDTH
   WINZONE(WINNUM,GADNUM,4)=Y+HEIGHT
   GADSTUFF(WINNUM,GADNUM,1)=STYLE
   '
   X=X+WININFO(WINNUM,1)
   Y=Y+WININFO(WINNUM,2)
   GAD_RAISEBOX_CREATE[X,Y,WIDTH,HEIGHT,STYLE]
   '
End Proc
Procedure GAD_SBUT_IN[WINNUM,GADNUM]
   '
   X=WINZONE(WINNUM,GADNUM,1)
   Y=WINZONE(WINNUM,GADNUM,2)
   WIDTH=WINZONE(WINNUM,GADNUM,3)-X
   HEIGHT=WINZONE(WINNUM,GADNUM,4)-Y
   STYLE=GADSTUFF(WINNUM,GADNUM,1)
   '
   X=X+WININFO(WINNUM,1)
   Y=Y+WININFO(WINNUM,2)
   GAD_LOWERBOX_CREATE[X,Y,WIDTH,HEIGHT,STYLE]
   '
End Proc
Procedure GAD_SBUT_OUT[WINNUM,GADNUM]
   '
   X=WINZONE(WINNUM,GADNUM,1)
   Y=WINZONE(WINNUM,GADNUM,2)
   WIDTH=WINZONE(WINNUM,GADNUM,3)-X
   HEIGHT=WINZONE(WINNUM,GADNUM,4)-Y
   STYLE=GADSTUFF(WINNUM,GADNUM,1)
   '
   X=X+WININFO(WINNUM,1)
   Y=Y+WININFO(WINNUM,2)
   '
   GAD_RAISEBOX_CREATE[X,Y,WIDTH,HEIGHT,STYLE]
   '
End Proc
'
'
' **Warning - Both file selector and gad_request use the very last window
'             id number. If there is a window there it will be destroyed.
'             Leave the last window free if you intend to use these procs!
'
Procedure WIN_FILE_SELECTOR[X,Y,WIDTH,TITLE$]
   '
   ' Hastily converted from my agads2. Dev next$ kept hanging my machine,
   ' so I put this crappy devs thing in instead. To get into your
   ' harddrive, type the device name in the top text gadget.
   '
   '
   WIDTH=WIDTH*8 : FILETEMP=0 : WC=WINCOUNT

   '
   WIN_CREATE[WC,X,Y,WIDTH+7,134,0,0,0,0]
   WIN_FRAMEWORK[WC,2,0,VDGREY,0,TITLE$]

   GAD_RAISEBOX_CREATE[X+4,Y+15,WIDTH,117,4]
   GAD_LOWERBOX_CREATE[X+10,Y+18,WIDTH-117,110,4]
'   GAD_VSLIDER_CREATE[WC,11,WIDTH-103,18,20,90,0,9]
'   GAD_VSLIDEBUT_CREATE[WC,12,11]
   '
   GAD_BUTTON_CREATE[WC,13,WIDTH-75,18,11," PARENT "]
   GAD_BUTTON_CREATE[WC,14,WIDTH-75,31,11,"  DEVS  "]
   GAD_BUTTON_CREATE[WC,5,WIDTH-75,104,11,"   OK   "]
   GAD_BUTTON_CREATE[WC,6,WIDTH-75,117,11," CANCEL "]
   GAD_CHECKBOX_CREATE[WC,10,WIDTH-75,65] : GAD_CHECKBOX_TICK[WC,10]
   Ink VBLACK : Text X+WIDTH-43,Y+73,"SIZES"
   '
   GAD_TEXT_CREATE[WC,7,12,19,(WIDTH/8)-16,Dir$,0]
   GAD_TEXT_CREATE[WC,8,12,115,(WIDTH/8)-16,"",0]
   '   Look 'ere ... a custom zone!
   WINZONE(WC,9,1)=12 : WINZONE(WC,9,2)=33
   WINZONE(WC,9,3)=WIDTH-109 : WINZONE(WC,9,4)=112
   '
   DPOS=0 : SIZE=1 : SELECTED=-1
   WIN_SETGFX[WC]
   '
   If FILELIST$(0)=""
      If Dir$=""
         Gosub FINDDEVS
      Else
         Gosub FINDDIR
      End If
   Else
      Gosub RETREIVEDIR
   End If
   '
   '
   Do

      WINSCAN : BUTTON=Param
      If WINSELECTED=WC
         X=WININFO(WC,1) : Y=WININFO(WC,2)

         If BUTTON=11 : Repeat : Wait Vbl : GAD_SLIDER_MOUSE_UPDATE[WC,11] : DPOS=Param : Gosub DISPDIR : Until Mouse Key=0 : End If
'         If BUTTON=12 : Repeat : GAD_VSLIDEBUT_UPDATE[WC,12] : DPOS=Param : Gosub DISPDIR : Until Mouse Key=0 : GAD_SLIDEOFF[WC,12] : End If
         If BUTTON=13 : Parent : Gosub FINDDIR : End If
         If BUTTON=14 or Mouse Key=2 : Repeat : Until Mouse Key=0 : Gosub FINDDEVS : BUTTON=0 : End If
         If BUTTON=9 : Gosub SELECTFILE : End If
      If BUTTON=7 : GAD_TEXT_INPUT[WC,7] : TEMP$=Param$ : If Exist(TEMP$) : Dir$=TEMP$ : Gosub FINDDIR : Else GAD_TEXT_SET[WC,7,Dir$,0,0] : End If : End If
         If BUTTON=8 : GAD_TEXT_INPUT[WC,8] : TEMP$=Param$ : If TEMP$<>"" : Goto LFILE : End If : End If
         If BUTTON=5 : TEMP$=GADTEXT$(WC,8) : Gosub STRIPTEMP : Goto LFILE : End If
         If BUTTON=6 or WINCLOSED : OUT$="" : Goto QUITIT : End If
         If BUTTON=10 : GAD_CHECKBOX_TICK[WC,10] : SIZE=Param : Gosub DISPDIR : End If
         If FILETEMP=1 : Goto LFILE : End If
         If X Screen(X Mouse)>X+12 and Y Screen(Y Mouse)>Y+33 and X Screen(X Mouse)<X+WIDTH-109 and Y Screen(Y Mouse)<Y+113
            SELECTED=((Y Screen(Y Mouse)-(Y+33))/8)+DPOS
         Else SELECTED=-1
         End If
         Gosub DISPDIR
      End If
   Loop
   '
   '
   FINDDEVS:
   For N=0 To 300
      FILELIST$(N)=""
   Next N
   N=0 : F=0 : DPOS=0
   Restore DEVDATA
   While F<17
      Read DE$
      If Exist(Right$(DE$,Len(DE$)-1))
         FILELIST$(N)=DE$+Space$(((WIDTH/8)-15)-Len(DE$))
         Inc N
      End If
      Inc F
   Wend
   GAD_SLIDER_CREATE[WC,11,WIDTH-103,18,20,111,N,10] : N=0
   Ink VBLUE
   Bar X+12,Y+33 To X+WIDTH-109,Y+113
   Gosub DISPDIR
   Return
   '
   '
   DEVDATA:
   Data "#DF0:","#DF1:","#DF2:","#DF3:","#HD0:","#DH0:","#HD1:","#DH1:","#HD2:","#DH2:"
   Data "#PC0:","#PC1:","#DS0:","#DS1:","#CD0:","#CD1:","#RAM:"
   '
   '
   DISPDIR:
   YT=Y+40
   Ink VBLACK,VBLUE
   For N=DPOS To DPOS+9
      Exit If FILELIST$(N)=""
      '
      If Left$(FILELIST$(N),1)="*" or Left$(FILELIST$(N),1)="#"
         If N=SELECTED
            Ink VBLUE,VWHITE
         Else
            Ink VWHITE,VBLUE
         End If
         TEMP$=Right$(FILELIST$(N),Len(FILELIST$(N))-1)
         Text X+13,YT,Left$(TEMP$,(WIDTH/8)-17)
      Else
         If N=SELECTED
            Ink VBLACK,VWHITE
         Else
            Ink VBLACK,VBLUE
         End If
         TEMP$=Right$(FILELIST$(N),Len(FILELIST$(N))-1)
         If SIZE=1
            Text X+13,YT,Left$(TEMP$,(WIDTH/8)-24)+Mid$(TEMP$,Len(TEMP$)-8,7)
         Else
            Text X+13,YT,Left$(TEMP$,(WIDTH/8)-17)
         End If
         '
      End If
      '
      Add YT,8
   Next N
   YT=0
   Return
   '
   '
   FINDDIR:
   For N=0 To 300
      FILELIST$(N)=""
   Next N
   N=0 : DPOS=0 : FILEDIR$=Dir$
   DI$=Dir First$(Dir$)
   FILELIST$(0)=DI$
   While FILELIST$(N)<>"" or N>300
      Inc N
      DI$=Dir Next$
      FILELIST$(N)=DI$
   Wend
   GAD_SLIDER_CREATE[WC,11,WIDTH-103,18,20,111,N,10] : N=0
   GAD_TEXT_SET[WC,7,Dir$,0,0]
   Ink VBLUE
   Bar X+12,Y+33 To X+WIDTH-109,Y+113
   Gosub DISPDIR
   Return
   '
   '
   SELECTFILE:
   NUM=(Y Screen(Y Mouse)-(Y+33))/8
   TEMP$=FILELIST$(DPOS+NUM)
   If TEMP$="" Then Return
   If Left$(TEMP$,1)=" "
      TEMP$=Right$(TEMP$,Len(TEMP$)-1)
      TEMP$=Left$(TEMP$,Len(TEMP$)-9) : Gosub STRIPTEMP
      If GADTEXT$(WC,8)=TEMP$ : FILETEMP=1 : Return : End If
      GAD_TEXT_SET[WC,8,TEMP$,0,0]
   Else
      FLAG$=Left$(TEMP$,1)
      TEMP$=Right$(TEMP$,Len(TEMP$)-1)
      While Mid$(TEMP$,Len(TEMP$),1)=" "
         TEMP$=Left$(TEMP$,Len(TEMP$)-1)
      Wend
      '
      If Exist(TEMP$)
         If FLAG$="*"
            Dir$=Dir$+TEMP$
         Else
            Dir$=TEMP$
         End If
         '
         Gosub FINDDIR
      End If
   End If
   '
   Repeat : Until Mouse Key=0
   Return
   '
   '
   STRIPTEMP:
   While Mid$(TEMP$,Len(TEMP$),1)=" "
      TEMP$=Left$(TEMP$,Len(TEMP$)-1)
   Wend
   Return
   '
   '
   RETREIVEDIR:
   N=0 : DPOS=0
   If Dir$=FILEDIR$
      While FILELIST$(N)<>"" or N>300
         Inc N
      Wend
      GAD_SLIDER_CREATE[WC,11,WIDTH-103,18,20,111,N,10] : N=0
      GAD_TEXT_SET[WC,7,Dir$,0,0]
      Ink VBLUE
      Bar X+12,Y+33 To X+WIDTH-109,Y+113
      Gosub DISPDIR
   Else
      Gosub FINDDIR
   End If
   Return
   '
   '
   LFILE:
   OUT$=Dir$+TEMP$

   QUITIT:
   WIN_CLOSE[WC]

End Proc[OUT$]
'
Procedure GAD_REQUEST[X,Y,TITLE$,MESSAGE$,MESSAGE2$,MESSAGE3$,BUTTON1$,BUTTON2$]
   '
   WC=WINCOUNT
   '
   '
   '
   XS=Len(TITLE$)+3
   If Len(MESSAGE$)>XS Then XS=Len(MESSAGE$)
   If Len(MESSAGE2$)>XS Then XS=Len(MESSAGE2$)
   If Len(MESSAGE3$)>XS Then XS=Len(MESSAGE3$)


   XSIZ=(XS*8)+28

   If XSIZ<(Len(BUTTON1$)*8)+(Len(BUTTON2$)*8)+25 Then XSIZ=(Len(BUTTON1$)*8)+(Len(BUTTON2$)*8)+27

   WIN_CREATE[WC,X,Y,XSIZ,58,XSIZ,58,XSIZ,58]
   WIN_FRAMEWORK[WC,1,1,0,VBLUE,TITLE$]

   If BUTTON1$<>"" Then GAD_BUTTON_CREATE[WC,5,5,43,12,BUTTON1$]
   If BUTTON2$<>"" Then GAD_BUTTON_CREATE[WC,6,XSIZ-(Len(BUTTON2$)*8)-11,43,12,BUTTON2$]

   Ink VWHITE,VBLUE
   '
   LTEKST=Len(MESSAGE$)*8
   XS=(XSIZ-LTEKST)/2
   Text X+1+XS,Y+22,MESSAGE$
   '
   LTEKST=Len(MESSAGE2$)*8
   XS=(XSIZ-LTEKST)/2
   Text X+1+XS,Y+30,MESSAGE2$
   '
   LTEKST=Len(MESSAGE3$)*8
   XS=(XSIZ-LTEKST)/2
   Text X+1+XS,Y+38,MESSAGE3$
   '
   ' below has to be done. Cant del a block which hasn't been made.
   WIN_SETGFX[WC]
   '
   Do
      Proc WINSCAN : BUT=Param
      If WINSELECTED=WC
         If BUT=5 : BUTTON=1 : Exit : End If
         If BUT=6 : BUTTON=2 : Exit : End If
      End If
   Loop
   '
   WIN_CLOSE[WC]
   '
End Proc[BUTTON]
'
' Below procedure is (supposed) to move any gadget to new coordinates
'  Use for redrawing gadgets after a window resize.
'
Procedure GAD_MOVE[WINNUM,GADNUM,X,Y]
   '
   Dim TMP(6)
   '
   ' get all the stuff
   '
   TYPE=WINZONE(WINNUM,GADNUM,0)
   OLDX=WINZONE(WINNUM,GADNUM,1)
   OLDY=WINZONE(WINNUM,GADNUM,2)
   WIDTH=WINZONE(WINNUM,GADNUM,3)-OLDX
   HEIGHT=WINZONE(WINNUM,GADNUM,4)-OLDY
   '
   For N=0 To 6
      TMP(N)=GADSTUFF(WINNUM,GADNUM,N)
   Next N
   TX$=GADTEXT$(WINNUM,GADNUM)
   '
   ' redraw and replace
   '
   If TYPE=1
      'button
      GAD_BUTTON_CREATE[WINNUM,GADNUM,X,Y,HEIGHT,TX$]
   Else If TYPE=5
      'text
      GAD_TEXT_CREATE[WINNUM,GADNUM,X,Y,TMP(0),TX$,TMP(1)]
   Else If TYPE=6
      'display
      GAD_DISPLAY_CREATE[WINNUM,GADNUM,X,Y,TMP(0),TX$]
   Else If TYPE=7
      'cycle
      VSTARTPOS=(TMP(1)-1)*TMP(0)
      If TMP(1)>1 : Inc VSTARTPOS : End If

      CYCL$=Mid$(TX$,VSTARTPOS,TMP(0))
      GAD_CYCLE_CREATE[WINNUM,GADNUM,X,Y,TMP(0),CYCL$]
   Else If TYPE=13
      'vslider
      GAD_SLIDER_CREATE[WINNUM,GADNUM,X,Y-1,WIDTH+1,HEIGHT+3,TMP(1)+TMP(2)-1,TMP(2)]
      GAD_SLIDER_UPDATE[WINNUM,GADNUM,TMP(5)]
   Else If TYPE=15
      'hslider
      GAD_HSLIDER_CREATE[WINNUM,GADNUM,X-1,Y,WIDTH+3,HEIGHT+1,TMP(1)+TMP(2)-1,TMP(2)]
      GAD_HSLIDER_UPDATE[WINNUM,GADNUM,TMP(5)]
   Else If TYPE=17
      'check
      GAD_CHECKBOX_CREATE[WINNUM,GADNUM,X,Y]
      If TMP(1) : GAD_CHECKBOX_TICK[WINNUM,GADNUM] : End If
   Else If TYPE=20
      'sbut
      GAD_SBUT_OUT[WINNUM,GADNUM]
   Else If TYPE=32
      'RADIO
      If GADRADIO(WINNUM,TMP(1))=GADNUM
         GAD_RADIOBUT_IN[WINNUM,GADNUM]
      Else
         GAD_RADIOBUT_OUT[WINNUM,GADNUM]
      End If
   Else If TYPE=34
      'scroll
      GAD_SCROLLBUT_CREATE[WINNUM,GADNUM,X,Y]
   End If

   If TYPE=13 or TYPE=15
      E=5
   Else
      E=6
   End If

   For N=0 To E
      GADSTUFF(WINNUM,GADNUM,N)=TMP(N)
   Next N

   GADTEXT$(WINNUM,GADNUM)=TX$
End Proc